<%
Response.AddHeader "Pragma","no-cache"
Response.AddHeader "cache-control","no-cache,must revalidate"
Response.Expires =-1

If session("Admin_aff") = "" Then
	response.redirect "login.asp"
	response.end
End If

%>
<% 

	fn = Trim(request("id"))

	If Len(fn) <= 0 Then
		response.redirect("login.asp")
		response.End
	else

		Response.Buffer = False 
		Server.ScriptTimeout = 30000 
	 
		Response.ContentType = "application/x-unknown" ' arbitrary 
		FPath = server.MapPath(".") & "\images\large\p" & fn & ".jpg"

		Response.AddHeader "Content-Disposition", "attachment; filename=" & fn  & ".jpg"
	 
		Set adoStream = CreateObject("ADODB.Stream") 
		chunk = 2048 
		adoStream.Open() 
		adoStream.Type = 1 
		adoStream.LoadFromFile(FPath) 
	 
		iSz = adoStream.Size 
	 
		Response.AddHeader "Content-Length", iSz 
	 
		For i = 1 To iSz \ chunk 
			If Not Response.IsClientConnected Then Exit For 
			Response.BinaryWrite adoStream.Read(chunk) 
		Next 
	 
		If iSz Mod chunk > 0 Then 
			If Response.IsClientConnected Then 
				Response.BinaryWrite adoStream.Read(iSz Mod chunk) 
			End If 
		End If 
	 
		adoStream.Close 
		Set adoStream = Nothing 
	 
		Response.End 
	End if
%>